inno setup教程解释脚本

天狗

;Inno Setup 是一个免费的 Windows 安装程序制作软件。
;第一次发表是在 1997 年，Inno Setup 今天在功能设置和稳定性上的竞争力可能已经超过一些商业的安装程序制作软件
;它是真正免费的软件，即使作为商业应用
;还有一个特点，压缩率特别高，特别适合VB软件，我这个安装打包后只有3.7M，其他打包工具5M多
;安装程序用编译脚本的方式创建，脚本其实就是一个类似 .INI 文件格式的 ASCII 码文本文件。 (它不象你想象的那么复杂!)
;脚本文件一般可以用安装程序编译器程序内置的编辑器进行编辑。在你编写完脚本后，下一个最终步骤就是选择安装程序编译器
;中的“编译”。创建完成后，就可以运行根据你脚本编译的安装程序了。
;按默认，这个安装程序创建在包含脚本文件目录下的名为“输出”目录中


[Setup]
;这个段包含用于安装程序和卸载程序的全局设置。某些提示对于你创建的任何安装程序都是必需的
;一个必需的指示，用以指定你正在安装的应用程序的标题。不包含版本号，与 AppVerName 指示用于同样的目的。AppName 始终在安装过程中显示在安装屏幕的左上角以及安装向导中
AppName=GOTVG工具栏
;这个必需的指示值应该与 AppName 的值相同 (或类似)，但它还应该包含程序的版本号
AppVerName=GOTVG工具栏 V3.31
;这是所有用于在 Windows 2000/XP 中添加/删除程序控件面板对话框中的“支持”信息中显示的内容。这些设置是可选的，在早期的 Windows 版本中无效
AppPublisher=sinyosoft
;这是所有用于在 Windows 2000/XP 中添加/删除程序控件面板对话框中的“支持”信息中显示的内容。这些设置是可选的，在早期的 Windows 版本中无效
AppPublisherURL=http://www.nbjk.net
AppSupportURL=http://www.nbjk.net
AppUpdatesURL=http://www.nbjk.net
;这个必需的指示值是用于选择目标位置向导面中的默认目录名，通常它用一个目录常量作为前缀，{pf}\\SinyoCDManager将显示:C:\\Program Files\\SinyoCDManager
DefaultDirName={pf}\\SinyoCDManager
;这个指示的值用是在向导的选择开始菜单文件夹页中使用的默认开始菜单文件夹名。如果这个指示是空白或未指定，它将用“默认”作为名字
DefaultGroupName=GOTVG工具栏
;指定许可协议文件名 (可选)，用 .txt 或 .rtf (富文本) 格式，在用户选择程序目标目录前显示
LicenseFile=F:\\资料保存\\GOTVG工作室安装包\\GOTVG工具栏\\Support\\Application\\License.txt
;指定“自述”文件名 (可选)，用 .txt 或 .rtf (富文本) 格式，用于在安装完成后显示
InfoAfterFile=F:\\资料保存\\GOTVG工作室安装包\\GOTVG工具栏\\Support\\Application\\请先读我.txt
;这是指定要在文件中使用的压缩方法，以及压缩标准
Compression=lzma
;如果设为 yes，固实压缩将启用。这会使所有文件一次性压缩
SolidCompression=yes

[Tasks]
;这个段是只选的。它定义安装程序在执行安装期间所有由用户定制的任务。这些任务以选项框和单选项形式在附加任务向导页中出现
; 注意: 下面的条目包含一个中文用语 (“创建桌面快捷方式”和“添加快捷方式”)。如果需要你可以翻译为其它语言。
Name: "desktopicon"; Description: "创建桌面快捷方式"; GroupDescription: "添加快捷方式:"; Flags: checkedonce
; 注意: 下面的条目包含一个中文用语 (“创建快速运行栏快捷方式”和“添加快捷方式”)。如果需要你可以翻译为其它语言。
Name: "quicklaunchicon"; Description: "创建快速运行栏快捷方式"; GroupDescription: "添加快捷方式:"; Flags: checkedonce

[Files]
;这是定义安装程序安装文件到用户系统中的可选文件段
;因这是VB软件，除软件本身包含的文件外，还必须包含相关的链接库
;以下即软件本身的文件，注：安装目录下有一个 "\\Data" 的子目录
Source: "F:\\资料保存\\GOTVG工作室安装包\\GOTVG工具栏\\Support\\Application\\CDManager.EXE"; DestDir: "{app}"; Flags: ignoreversion
Source: "F:\\资料保存\\GOTVG工作室安装包\\GOTVG工具栏\\Support\\Application\\Data\\*"; DestDir: "{app}\\Data"; Flags: ignoreversion
Source: "F:\\资料保存\\GOTVG工作室安装包\\GOTVG工具栏\\Support\\Application\\请先读我.txt"; DestDir: "{app}"; Flags: ignoreversion
Source: "F:\\资料保存\\GOTVG工作室安装包\\GOTVG工具栏\\Support\\Application\\CDManager.exe.manifest"; DestDir: "{app}"; Flags: ignoreversion
Source: "F:\\资料保存\\GOTVG工作室安装包\\GOTVG工具栏\\Support\\Application\\License.txt"; DestDir: "{app}"; Flags: ignoreversion
Source: "F:\\资料保存\\GOTVG工作室安装包\\GOTVG工具栏\\Support\\Application\\GOTVG工具栏帮助.chm"; DestDir: "{app}"; Flags: ignoreversion
Source: "F:\\资料保存\\GOTVG工作室安装包\\GOTVG工具栏\\Support\\Application\\Data\\*"; DestDir: "{app}"; Flags: ignoreversion recursesubdirs
; 注意: 不要在任何共享系统文件中使用“Flags: ignoreversion”

;以下是VB6 RunTime，本工作室严格测试过，可保证在Windows98第一版下正常运行VB6软件
Source: "F:\\资料保存\\GOTVG工作室安装包\\Support\\vb6RunTime\\ASYCFILT.DLL"; DestDir: "{sys}"; CopyMode: alwaysskipifsameorolder; Flags: restartreplace sharedfile
;注意COMCAT.DLL版本号必须是4.71的，不能用5.0版本
Source: "F:\\资料保存\\GOTVG工作室安装包\\Support\\vb6RunTime\\COMCAT.DLL"; DestDir: "{sys}"; CopyMode: alwaysskipifsameorolder; Flags: restartreplace sharedfile regserver
Source: "F:\\资料保存\\GOTVG工作室安装包\\Support\\vb6RunTime\\EXPSRV.DLL"; DestDir: "{sys}"; CopyMode: alwaysskipifsameorolder; Flags: restartreplace sharedfile
Source: "F:\\资料保存\\GOTVG工作室安装包\\Support\\vb6RunTime\\MsRepl35.dll"; DestDir: "{sys}"; CopyMode: alwaysskipifsameorolder; Flags: restartreplace sharedfile
Source: "F:\\资料保存\\GOTVG工作室安装包\\Support\\vb6RunTime\\MSVBVM60.DLL"; DestDir: "{sys}"; CopyMode: alwaysskipifsameorolder; Flags: restartreplace sharedfile regserver
Source: "F:\\资料保存\\GOTVG工作室安装包\\Support\\vb6RunTime\\MSVCRT40.DLL"; DestDir: "{sys}"; CopyMode: alwaysskipifsameorolder; Flags: restartreplace sharedfile
Source: "F:\\资料保存\\GOTVG工作室安装包\\Support\\vb6RunTime\\OLEAUT32.DLL"; DestDir: "{sys}"; CopyMode: alwaysskipifsameorolder; Flags: restartreplace sharedfile regserver
Source: "F:\\资料保存\\GOTVG工作室安装包\\Support\\vb6RunTime\\OLEPRO32.DLL"; DestDir: "{sys}"; CopyMode: alwaysskipifsameorolder; Flags: restartreplace sharedfile regserver
Source: "F:\\资料保存\\GOTVG工作室安装包\\Support\\vb6RunTime\\STDOLE2.TLB"; DestDir: "{sys}"; CopyMode: alwaysskipifsameorolder; Flags: restartreplace sharedfile
Source: "F:\\资料保存\\GOTVG工作室安装包\\Support\\vb6RunTime\\VB6CHS.DLL"; DestDir: "{sys}"; CopyMode: alwaysskipifsameorolder; Flags: restartreplace sharedfile
;以下是OCX控件及DAO组件
;这个软件用的是DAO3.5、MSFLXGRD、MSCOMCT2
Source: "F:\\资料保存\\GOTVG工作室安装包\\Support\\SYSTEM\\DAO350.DLL"; DestDir: "{sys}"; CopyMode: alwaysskipifsameorolder; Flags: restartreplace sharedfile regserver
Source: "F:\\资料保存\\GOTVG工作室安装包\\Support\\SYSTEM\\DiskID32.dll"; DestDir: "{sys}"; CopyMode: alwaysskipifsameorolder; Flags: restartreplace sharedfile
Source: "F:\\资料保存\\GOTVG工作室安装包\\Support\\SYSTEM\\FLXGDCHS.DLL"; DestDir: "{sys}"; CopyMode: alwaysskipifsameorolder; Flags: restartreplace sharedfile
Source: "F:\\资料保存\\GOTVG工作室安装包\\Support\\SYSTEM\\MSCC2CHS.DLL"; DestDir: "{sys}"; CopyMode: alwaysskipifsameorolder; Flags: restartreplace sharedfile
Source: "F:\\资料保存\\GOTVG工作室安装包\\Support\\SYSTEM\\MSCMCCHS.DLL"; DestDir: "{sys}"; CopyMode: alwaysskipifsameorolder; Flags: restartreplace sharedfile
Source: "F:\\资料保存\\GOTVG工作室安装包\\Support\\SYSTEM\\MSCOMCT2.OCX"; DestDir: "{sys}"; CopyMode: alwaysskipifsameorolder; Flags: restartreplace sharedfile regserver
Source: "F:\\资料保存\\GOTVG工作室安装包\\Support\\SYSTEM\\MSCOMCTL.OCX"; DestDir: "{sys}"; CopyMode: alwaysskipifsameorolder; Flags: restartreplace sharedfile regserver
Source: "F:\\资料保存\\GOTVG工作室安装包\\Support\\SYSTEM\\MSFLXGRD.OCX"; DestDir: "{sys}"; CopyMode: alwaysskipifsameorolder; Flags: restartreplace sharedfile regserver
Source: "F:\\资料保存\\GOTVG工作室安装包\\Support\\SYSTEM\\MSJet35.dll"; DestDir: "{sys}"; CopyMode: alwaysskipifsameorolder; Flags: restartreplace sharedfile
Source: "F:\\资料保存\\GOTVG工作室安装包\\Support\\SYSTEM\\MSJInt35.dll"; DestDir: "{sys}"; CopyMode: alwaysskipifsameorolder; Flags: restartreplace sharedfile
Source: "F:\\资料保存\\GOTVG工作室安装包\\Support\\SYSTEM\\MSJtER35.dll"; DestDir: "{sys}"; CopyMode: alwaysskipifsameorolder; Flags: restartreplace sharedfile
Source: "F:\\资料保存\\GOTVG工作室安装包\\Support\\SYSTEM\\MSRD2x35.dll"; DestDir: "{sys}"; CopyMode: alwaysskipifsameorolder; Flags: restartreplace sharedfile regserver
Source: "F:\\资料保存\\GOTVG工作室安装包\\Support\\SYSTEM\\VB5DB.dll"; DestDir: "{sys}"; CopyMode: alwaysskipifsameorolder; Flags: restartreplace sharedfile
Source: "F:\\资料保存\\GOTVG工作室安装包\\Support\\SYSTEM\\VBAJET32.DLL"; DestDir: "{sys}"; CopyMode: alwaysskipifsameorolder; Flags: restartreplace sharedfile

;以下是本安装特别需要的
;还用了个免费的“魔鬼XP按钮控件”，在此一并感谢作者，在98、2K、XP-sp2下测试通过，占用资源一般
;发现了几个BUG（不太影响使用），准备提交给作者
Source: "F:\\资料保存\\GOTVG工作室安装包\\GOTVG工具栏\\Support\\UserControl\\MageanButtonV1_2_0.ocx"; DestDir: "{sys}"; CopyMode: alwaysskipifsameorolder; Flags: restartreplace sharedfile regserver
;这是上一个控件需要的，必须打包上
Source: "F:\\资料保存\\GOTVG工作室安装包\\GOTVG工具栏\\Support\\UserControl\\Picclp32.ocx"; DestDir: "{sys}"; CopyMode: alwaysskipifsameorolder; Flags: restartreplace sharedfile regserver

[INI]
;这是你希望安装程序在用户系统中设置 .INI 文件条目的可选段。
;写一个文件“访问我们.url”用于访问作者网站
Filename: "{app}\\访问我们.url"; Section: "InternetShortcut"; Key: "URL"; String: "http://www.nbjk.net"

[Icons]
;这个可选段定义所有创建在开始菜单和/或其它位置 (比如桌面) 的快捷方式
Name: "{group}\\GOTVG工具栏"; Filename: "{app}\\CDManager.EXE"
Name: "{group}\\GOTVG工具栏帮助"; Filename: "{app}\\GOTVG工具栏帮助.chm"
Name: "{group}\\请先读我"; Filename: "{app}\\请先读我.txt"

; 注意: 下列条目包含一个中文用语 (“网站”)。如果需要你可以翻译为其它语言。
Name: "{group}\\访问主页"; Filename: "{app}\\访问我们.url"
Name: "{userdesktop}\\GOTVG工具栏"; Filename: "{app}\\CDManager.EXE"; Tasks: desktopicon
Name: "{userappdata}\\Microsoft\\Internet Explorer\\Quick Launch\\GOTVG工具栏"; Filename: "{app}\\CDManager.EXE"; Tasks: quicklaunchicon

[Run]
; 注意: 下列条目包含一个中文用语 (“运行”)。如果需要你可以翻译为其它语言。
;[Run] 段是可选的，用来指定程序完成安装后、在安装程序显示最终对话框之前要执行的程序
Filename: "{app}\\CDManager.EXE"; Description: "运行 GOTVG工具栏"; Flags: nowait postinstall skipifsilent

[UninstallDelete]
;这个可选段定义你想让卸载程序删除除用 [Files] 或 [Dirs] 条目安装/创建外的其它文件或目录，或由你应用程序创建的一些公共使用的 .INI 文件。卸载程序在卸载时最后一步处理这些条目
Type: files; Name: "{app}\\访问我们.url"

============================================================================


实例:


[Types]
Name: "full"; Description: "完全安装"
Name: "compact"; Description: "典型安装"
Name: "custom"; Description: "自定义安装"; Flags: iscustom

[Components]
Name: "main"; Description: "主要文件"; Types: full compact
Name: "1"; Description: "语言文件"; Types: full
Name: "2"; Description: "脚本例子"; Types: full
Name: "3"; Description: "使用安装程序关联注册表"; Types: full compact
Name: "4"; Description: "使用软件自身的关联注册表"; Types: full
Name: "5"; Description: "InnoSetup Icon Replacer 0.3"; Types: full

[Tasks]
Name: "desktopicon"; Description: "在桌面上创建图标(&D)"; GroupDescription: "添加图标："
Name: "quicklaunchicon"; Description: "在快速启动栏创建图标(&Q)"; GroupDescription: "添加图标："; Flags: unchecked
; 如果使用了下面 [Registry] 部分我自行编写的注册表脚本可不要下面的这行语句。
Name: fileassoc; Description: "将 Inno Setup 与 .iss 文件建立关联(&A)"; Components: 4

[Files]
Source: "E:\Program Files\Inno Setup 4\Compil32.exe"; DestDir: "{app}"; CopyMode: alwaysoverwrite; Components: main
Source: "E:\Program Files\Inno Setup 4\*.*"; DestDir: "{app}"; CopyMode: alwaysoverwrite; Components: main
Source: "E:\Program Files\Inno Setup 4\Language\*.*"; DestDir: "{app}\Language\"; CopyMode: alwaysoverwrite; Components: 1
Source: "E:\Program Files\Inno Setup 4\Examples\MyDll\C\*.*"; DestDir: "{app}\Examples\MyDll\C\"; CopyMode: alwaysoverwrite; Components: 2
Source: "E:\Program Files\Inno Setup 4\Examples\MyDll\Delphi\*.*"; DestDir: "{app}\Examples\MyDll\Delphi\"; CopyMode: alwaysoverwrite; Components: 2
Source: "E:\Program Files\Inno Setup 4\Examples\*.*"; DestDir: "{app}\Examples\"; CopyMode: alwaysoverwrite; Components: 2
Source: "E:\Program Files\Inno Setup 4\InnoSetup Icon Replacer 0.3\*.*"; DestDir: "{app}\Examples\"; CopyMode: alwaysoverwrite; Components: 5

[Icons]
; 注意: 要实现在图标的属性中的“起始位置：”，能够显示路径的话需加（WorkingDir: "{app}"）代码。例:workingdir:"{app}\2\"
[Icons]
Name: "{group}\Inno Setup 4 (汉化版)"; Filename: "{app}\Compil32.exe"; WorkingDir: "{app}"; Components: main
Name: "{group}\InnoSetup Icon Replacer 0.3 (汉化版)"; Filename: "{app}\InnoSetup Icon Replacer 0.3\iconedit.exe"; WorkingDir: "{app}\InnoSetup Icon Replacer 0.3\"; Components: 5
Name: "{group}\Inno Setup 主页"; Filename: "{app}\Compil32.url"; WorkingDir: "{app}"; Components: main
Name: "{group}\卸载 Inno Setup 4 (汉化版)"; Filename: "{uninstallexe}"; WorkingDir: "{app}"; Components: main
Name: "{group}\帮助"; Filename: "{app}\Shelpm.hlp"; WorkingDir: "{app}"; Components: main
Name: "{group}\问与答"; Filename: "{app}\isfaq.htm"; WorkingDir: "{app}"; Components: main
Name: "{group}\修正历史"; Filename: "{app}\whatsnew.htm"; WorkingDir: "{app}"; Components: main
Name: "{userdesktop}\Inno Setup 4 (汉化版)"; Filename: "{app}\Compil32.exe"; WorkingDir: "{app}"; Tasks: desktopicon; MinVersion: 4,4; Components: main
Name: "{userdesktop}\InnoSetup Icon Replacer 0.3 (汉化版)"; Filename: "{app}\InnoSetup Icon Replacer 0.3\iconedit.exe"; WorkingDir: "{app}\InnoSetup Icon Replacer 0.3\"; Tasks: desktopicon; MinVersion: 4,4; Components: 5